home *** CD-ROM | disk | FTP | other *** search
/ Developer CD Series 1992 June: ROMin Holiday / ADC Developer CD (1992-06) (''ROMin Holiday'')_iso / Developer Connection - 06-1992.iso / Development Platforms / Apple II / Essentials / Miscellaneous Disk Images / ProDOS Basic Examples / PROGRAMS / ADDRESS.bas next >
Encoding:
BASIC Source File  |  1983-10-01  |  1.6 KB  |  56 lines
  1. 10 D$ =  CHR$(4)
  2. 20 F$ = "/EXAMPLES/DATA/BLACK.BOOK"
  3. 30  HOME 
  4. 40  PRINT "WHAT WOULD YOU LIKE TO DO?": PRINT 
  5. 50  PRINT "  1  ENTER A NEW ADDRESS"
  6. 60  PRINT "  2  LOOK UP AN ADDRESS"
  7. 70  PRINT "  3  END": PRINT 
  8. 80  INPUT "TYPE A NUMBER AND PRESS RETURN  ";C$
  9. 90 C =  VAL(C$): PRINT 
  10. 100  IF C <1  OR C >3  THEN  GOTO 30
  11. 110  IF C = 1  THEN  GOSUB 1000
  12. 120  IF C = 2  THEN  GOSUB 2000
  13. 130  IF C = 3  THEN  END 
  14. 140  GOTO 30
  15. 1000  REM  READ NEW  INFO
  16. 1010  INPUT "NAME:         ";N$
  17. 1020  INPUT "ADDRESS:      ";A$
  18. 1030  INPUT "CITY:         ";C$
  19. 1040  INPUT "STATE:        ";S$
  20. 1050  INPUT "ZIP CODE:     ";Z$
  21. 1060  INPUT "PHONE:        ";P$
  22. 1070  PRINT D$;"OPEN ";F$;",L200"
  23. 1080  PRINT D$;"READ ";F$;",R0"
  24. 1090  INPUT TR:TR = TR +1
  25. 1100  PRINT D$;"WRITE ";F$;",R";TR
  26. 1110  PRINT N$: PRINT A$: PRINT C$
  27. 1120  PRINT S$: PRINT Z$: PRINT P$
  28. 1130  PRINT D$;"WRITE ";F$;",R0"
  29. 1140  PRINT TR
  30. 1150  PRINT D$;"CLOSE ";F$
  31. 1160  RETURN 
  32. 2000  PRINT D$;"OPEN ";F$;",L200"
  33. 2010  PRINT D$;"READ ";F$;",R0"
  34. 2020  INPUT TR: REM  GET # OF RECORDS
  35. 2030  IF TR = 0  THEN  GOTO 2210
  36. 2040  HOME 
  37. 2050  PRINT "WHOSE ADDRESS DO YOU WANT? ": PRINT 
  38. 2060  FOR I = 1 TO TR
  39. 2070 : PRINT D$;"READ ";F$;",R";I
  40. 2080 : INPUT N$
  41. 2090 : PRINT I,N$
  42. 2100  NEXT I
  43. 2110  PRINT D$: PRINT 
  44. 2120  INPUT "TYPE A NUMBER AND PRESS RETURN  ";R$
  45. 2130 R =  VAL(R$)
  46. 2140  IF R <1  OR R >TR  THEN  GOTO 2120
  47. 2150  HOME 
  48. 2160  PRINT D$;"READ ";F$;",R";R
  49. 2170  INPUT N$,A$,C$,S$,Z$,P$
  50. 2180  PRINT N$: PRINT A$
  51. 2190  PRINT C$,S$
  52. 2200  PRINT Z$: PRINT P$
  53. 2210  PRINT D$;"CLOSE ";F$
  54. 2220  VTAB 23: HTAB 8
  55. 2230  INPUT "PRESS RETURN TO CONTINUE";T$
  56. 2240  RETURN